/*
	FARGOS Development, LLC Sample Programs
	Copyright (C) 2002 FARGOS Development, LLC.  All rights reserved.
	mailto:support@fargos.net for assistance.

NOTE:  in the future, enhanced versions of these classes may be added to
the FARGOS/VISTA Object Management Environment core within the Standard
namespace.  Developers can avoid any potential conflict if they specify
an explicit namespace when creating instances of the sample classes.
*/

%include <OMEcore.o2h>

class SOAPservice {
/*!
Provides inheritable utility functions useful for applications
performing SOAP-based interactions.  The class class=WSDLtoOIL2
generates OIL2 classes that utilize class=SOAPservice.
!*/
	oid	queryObj;
} inherits from Object;

SOAPservice:create()
{
}

SOAPservice:delete()
{
}

SOAPservice:issueRequest(string targetURL, string packet)
{
	assoc	acl;
	any	hdrs;
	string	dest;

//display("Send query to ", targetURL, "\n");
display("XML document would be:\n", packet,"\n");
	dest = targetURL;
	acl = makeDefaultACL();
//dest = "http://localhost:4321";
	queryObj = send "createObject"("HTTPrequest", acl, "POST",
		dest, "localhost", "80", nil,
		"text/xml; charset=\"utf-8\"", packet, hdrs) to ObjectCreator;
	return (0);
}

SOAPservice:receiveResponse()
{
	any	result, xml, elem;

	result = send "getResponse" to queryObj;
	queryObj = nil;
	// automatic delete of HTTPrequest after getResponse method 
display("receiveResponse result=", result, "\n");
	// result[0] = MIME header;
	// result[1] = body of response
	// result[2] = HTTP response status line

	// TO DO:  handle error cases:
	if (result[2] == "") {
		return (nil);	// no response
	}
	// tokenize result[2], get status code
	if (findSubstring(result[1], "<?xml") == -1) {
		return (nil);	// not an XML document
	}

	xml = parseXML(result[1]);
	elem = call "openEnvelope"(xml);
	return (elem);
}

SOAPservice:openEnvelope(array xml)
{
	any	body, elem;

	if (xml[1] != "SOAP-ENV:Envelope") {
display("Not a SOAP-ENV:Envelope: ", xml[1], "\n");
		return (nil);
	}
	for body in xml[0] do {
		if (body[1] != "SOAP-ENV:Body") {
display("Not a SOAP-ENV:Body: ", body[1], "\n");
		return (nil);
		}
		for elem in body[0] do {
			return (elem);
		}
	}
	return (nil);
}

SOAPservice:getSOAPenvelopeHeader(string envelopeName, string namespace,
	string encodingStyle)
{
	set	lines;

	lines += "<?xml version='1.0' encoding='UTF-8'?>\n\n";
	lines += "<SOAP-ENV:Envelope xmlns:SOAP-ENV=\"http://schemas.xmlsoap.org/soap/envelope/\" xmlns:xsi=\"http://www.w3.org/1999/XMLschema-instance\" xmlns:xsd=\"http://www.w3.org/1999/XMLSchema\">\n";
	lines += "  <SOAP-ENV:Body>\n";
	lines += "    <ns1:";
	lines += envelopeName;
	lines += " xmlns:ns1=\"";
	lines += namespace;
	lines += "\" SOAP-ENV:encodingStyle=\"";
	lines += encodingStyle;
	lines += "\">\n";
	return (lines);
}

SOAPservice:getSOAPenvelopeClosing(string envelopeName)
{
	set	lines;

	lines += "    </ns1:";
	lines += envelopeName;
	lines += ">\n";
	lines += "  </SOAP-ENV:Body>\n";
	lines += "</SOAP-ENV:Envelope>\n";
	return (lines);
}